session-android/build.gradle

buildscript {
    repositories {
        google()
        mavenCentral()
        if (project.hasProperty('huawei')) maven {
            url 'https://developer.huawei.com/repo/'
            content {
                includeGroup 'com.huawei.agconnect'
            }
        }
    }

    dependencies {
        classpath "com.android.tools.build:gradle:$gradlePluginVersion"
        classpath files('libs/gradle-witness.jar')
        classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:$kotlinVersion"
        classpath "org.jetbrains.kotlin:kotlin-serialization:$kotlinVersion"
        classpath "com.google.gms:google-services:$googleServicesVersion"
        classpath "com.squareup:javapoet:1.13.0"
        if (project.hasProperty('huawei')) classpath 'com.huawei.agconnect:agcp:1.9.1.300'
    }
}

// List plugins AND their versions here, but don't apply. This allows you to use the plugin
// in your module without specifying the version.
plugins {
    id 'com.google.devtools.ksp' version "$kotlinVersion-1.0.20" apply false
    id 'com.google.dagger.hilt.android' version "$daggerHiltVersion" apply false
}

allprojects {
    repositories {
        google()
        mavenCentral()
        maven {
            url "https://raw.github.com/signalapp/maven/master/photoview/releases/"
            content {
                includeGroupByRegex "com\\.github\\.chrisbanes.*"
            }
        }
        maven {
            url "https://raw.github.com/signalapp/maven/master/shortcutbadger/releases/"
            content {
                includeGroupByRegex "me\\.leolin.*"
            }
        }
        maven {
            url "https://raw.github.com/signalapp/maven/master/circular-progress-button/releases/"
            content {
                includeGroupByRegex "com\\.github\\.dmytrodanylyk\\.circular-progress-button\\.*"
            }
        }
        maven {
            url "https://raw.github.com/signalapp/maven/master/sqlcipher/release/"
            content {
                includeGroupByRegex "org\\.signal.*"
            }
        }
        jcenter()
        maven { url "https://jitpack.io" }
        if (project.hasProperty('huawei')) maven {
            url 'https://developer.huawei.com/repo/'
            content {
                includeGroup 'com.huawei.android.hms'
                includeGroup 'com.huawei.agconnect'
                includeGroup 'com.huawei.hmf'
                includeGroup 'com.huawei.hms'
            }
        }
    }

    project.ext {
        androidMinimumSdkVersion = 23
        androidTargetSdkVersion  = 34
        androidCompileSdkVersion = 34
    }
}